Tengo un formulario en modo emergente, lo que necesito es 
que el Access esté minimizado y sólo se vea este 
formulario. Con un acceso directo indicando que el Access 
se ejecute minimizado lo resuelvo, pero necesitaría saber 
si se puede hacer por código...


MCPEGASUS
=========

Option Compare Database
Option Explicit

    Private Declare Function IsWindowVisible Lib "user32" (ByVal hwnd As Long) As Long

    Dim dwReturn As Long

    Const SW_HIDE = 0
    Const SW_SHOWNORMAL = 1
    Const SW_SHOWMINIMIZED = 2
    Const SW_SHOWMAXIMIZED = 3

    Private Declare Function ShowWindow Lib "user32" (ByVal hwnd As Long, _
        ByVal nCmdShow As Long) As Long

Private Sub demofA()

    MsgBox fAccessWindow("Show", False, True)

End Sub

Public Function fAccessWindow(Optional Procedure As String, _
                Optional SwitchStatus As Boolean, _
                Optional StatusCheck As Boolean) As Boolean

'Última actualización: 27/01/2002

'La sintaxis del Procedimiento consta de estos argumentos:
'Parte                          Descripción
'-------------------------------------------------------------------------------------------
'Procedure:         Requerido.  Hide = Se esconde totalmente la venta principal del Access. _
                                Show = Maximiza la ventana principal del
Access. _
                                Minimize = Minimiza la ventana principal del Access.

'SwitchStatus       Requerido.  True = Dependiendo de otro parámetro, esconde la _
                                            ventana principal del Access. _
                                False = No hace nada.

    If Procedure = "Hide" Then
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
    ElseIf Procedure = "Show" Then
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMAXIMIZED)
    ElseIf Procedure = "Minimize" Then
        dwReturn = ShowWindow(Application.hWndAccessApp, SW_SHOWMINIMIZED)
    End If

    If SwitchStatus = True Then
        If IsWindowVisible(hWndAccessApp) = 1 Then
            dwReturn = ShowWindow(Application.hWndAccessApp, SW_HIDE)
        Else
            dwReturn = ShowWindow(Application.hWndAccessApp,SW_SHOWMAXIMIZED)
        End If
    End If

    If StatusCheck = True Then
        If IsWindowVisible(hWndAccessApp) = 0 Then
            fAccessWindow = False
        ElseIf IsWindowVisible(hWndAccessApp) = 1 Then
            fAccessWindow = True
        End If
    End If

End Function

    Source: geocities.com/es/ensolva/Descargas/Documentos

               ( geocities.com/es/ensolva/Descargas)                   ( geocities.com/es/ensolva)                   ( geocities.com/es)