Program Tambah Data.

Pada modul sebelumnya kita telah menggunakan Connection untuk melakukan koneksi ke suatu data source, dan menggunakan Command untuk menjalankan perintah SQL untuk pembuatan tabel.

Berikut ini kita akan menggunakan DataAdapter dan DataSet untuk pengolahan data.

DataAdapter, merupakan objek .Net Framework Data Provider untuk mempopulasikan data ke Dataset, dan melakukan update data ke data source.

DataSet, merupakan cache dari data yang diambil dari data source melalui provider. Objek DataSet menggunakan scenario disconnected yang memang merupakan tujuan dari ADO.Net untuk mendukung model pemrograman n-Tier dan XML.

Catatan

• DataAdapter merupakan jembatan antara data source dengan DataSet. DataAdapter menggunakan objek  Command untuk menjalankan perintah-perintah SQL terhadap data source untuk memuat data ke DataSet, dan melakukan rekonsiliasi terhadap perubahan (tambah, perbaiki, dan hapus) data pada  DataSet kembali ke data source.
• Anda bisa membayangkan DataSet sebagai Recordset disconnected pada ADO, tetapi DataSet dapat terdiri dari beberapa DataTable yang berasal dari provider yang berbeda dan memiliki relation satu sama yang lain.

Tambah Data Tabel Barang

Imports System.Data.OleDb
Module Module3
    Public Sub main()
        Dim Oledbconn As OleDb.OleDbConnection
        Dim OledbComm As OleDb.OleDbCommand
        Dim OledbDA As OleDb.OleDbDataAdapter
        Dim ODS As New DataSet
        Dim sSQL As String
        Dim ODR As DataRow
        Dim ODC As OleDbCommandBuilder
        'Buat objek connection
        Oledbconn = New OleDbConnection("Provider=Microsoft.Jet.OleDb.4.0; Data Source=D:\BelajarVBnet\Belajar.mdb;")
        sSQL = "Select * From Barang"
        'Buat objek command untuk menjalankan SQL
        OledbComm = New OleDbCommand(sSQL, Oledbconn)
        OledbComm.CommandType = CommandType.Text
        'Buat objek dataadapter sebagai jembatan bagi DataSet
        OledbDA = New OleDbDataAdapter(OledbComm)
        'Isi data ke DataTable Barang di DataSet melalui DataAdapter
        OledbDA.Fill(ODS, "Barang")
        'Membuat objek datarow untuk record baru
        ODR = ODS.Tables("Barang").NewRow
        'Isi masing-masing field pada objek datarow
        ODR("KodeBar") = "VBnet"
        ODR("Keterangan") = "Milist Indoprog-VBnet"
        ODR("Satuan") = "Email"
        ODR("Harga") = 0
        'Tambah objek datarow ke DataTable Barang
        ODS.Tables("Barang").Rows.Add(ODR)
        'Generate perintah SQL untuk update data
        ODC = New OleDbCommandBuilder(OledbDA)
        'Lakukan update data dari DataSet ke data source
        OledbDA.Update(ODS, "Barang")
        Oledbconn.Close()
    End Sub
End Module