/* REXX */                                                            
/******************************************************************/  
/*  REVOKE A USERID AND ADD TEXT TO THE INSTALLATION-DATA FIELD   */  
/*  SHOWING THE USERID WAS TERMED AND THE DATE.                   */  
/*                                                                */  
/*  S.NEELAND  3/22/2004                                          */  
/******************************************************************/  
                                                                      
/*----- GET THE USERID TO POCESS ----------------*/                   
  PARSE ARG $UID $DATE .                                              
  IF $UID = '' THEN DO                                                
     SAY 'ENTER USERID TO REVOKE:'                                    
     PULL $UID                                                        
     IF $UID = '' THEN DO                                             
        SAY 'NO USERID ENTERED.  EXITING'                             
        EXIT                                                          
     END  /* ID $UID...  */                                           
  END  /* IF $UID...  */                                              
  $UID = STRIP($UID)                                                  
  IF $DATE = '' THEN $DATE = DATE('U')                                
                                                                      
/*----- REVOKE THE USERID -----------------------*/   
/*-------  Auditor flag set so that the ---------*/
/*-------  HelpDesk cannot reset the password ---*/
                   
  SAY '1. REVOKING USERID...'                                           
  "ALU" $UID "REVOKE AUDITOR"                                           
  IF RC <>0 THEN DO                                                     
     SAY '**********************************************************'   
     SAY '     USERID' $UID 'IS INVALID.  EXITING...'                   
     SAY '**********************************************************'   
     EXIT                                                               
  END  /* IF RC...  */                                                  
                                                                        
                                                                        
/*--------  GET RACF USERID PROFILE INFO --------------*/               
  SAY '2. UPDATING INSTALLATION-DATA INFORMATION...'                    
  $TEXT = 'INSTALLATION-DATA'                                           
  $DATA = ''                                                            
                                                                        
/*----- GET THE USERID INFORMATION --------------*/                     
  X = OUTTRAP('LIST.',20)                                               
    "LU" $UID                                                           
  X = OUTTRAP('OFF')                                                    
                                                                        
/*----- FIND THE INSTALLATION-DATA VALUE --------*/                     
  DO $LOOP=6 TO 10                                               
     $FOUND = POS($TEXT,LIST.$LOOP)                              
     IF $FOUND = 0 THEN ITERATE $LOOP                            
      $CHECK = SUBSTR(LIST.$LOOP,2,18)                           
      IF $CHECK = 'INSTALLATION-DATA=' THEN                      
         PARSE VAR LIST.$LOOP . 'INSTALLATION-DATA=' $DATA       
      LEAVE $LOOP                                                
  END  /* DO $LOOP...  */                                        
  $DATA = STRIP($DATA)                                           
                                                                 
/*----- BUILD THE NEW INSTALLATION-DATA VALUE ---*/              
  $DATA = $DATA||' ***TERM*** '||$DATE||'   'LEFT(USERID(),2)    
  "ALU" $UID "DATA('"$DATA"')"                                   
                                                                 
  SAY '3. DONE.'                                                 
  SAY ; SAY ; SAY ; "LU" $UID                                    
EXIT                                                             
**************************** Bottom of Data *********************

    Source: geocities.com/steveneeland