Proyectos en LogoWriter

El Objetivo del juego es hacer que la tortuga llege a la laguna. Para esto no debe chocar con las arañas y tampoco debe pasar por las telarañas. Usted puede variar el juego para hacerlo un poco mas fácil o mas interesante.

He tenido problemas con el codigo html, ni no visualiza todo el programa puede hacer lo siguiente

# Author : A. Bradley
# Date   : 10/8/95
#
# Adaptado y traducido por : 
#                    Samuel Escobar
#         
# -----------------
# TODO Para COMENZAR
# -----------------
#
# !RECUERDA QUE NUM LOCK 
#     DEBE ESTAR ACTIVO
#  La figura 79 debe ser una aran~a

Para BEGIN
muestra [ ****** RECUERDA ****** ]
muestra [NUM LOCK DEBE ESTAR ACTIVO]
fin


Para SETUPGOOD
dile 0
sp
da "FACING 8
da "GOODX -134
da "GOODY 78
fx :GOODX
fy :GOODY
fin

Para SETUPBAD
dile 1
ffig 79
mt 
da "BADX 100
da "BADY 50
fx :BADX
fy :BADY
fin

Para SETUPBAD1
dile 2
FFIG 79
mt 
da "BADX1 -50
da "BADY1 -50
fx :BADX1
fy :BADY1
fin

Para SETUPBAD2
dile 3
FFIG 79
mt 
da "BADX2 0
da "BADY2 -150
fx :BADX2
fy :BADY2
fin


Para GOODGUY
dile 0 
fcolor 1
da "GOODX entero COORX
da "GOODY entero COORY
si COORX > 150 [fx 145]
si COORX < -150 [fx -145]
si COORY > 80 [fy 75]
si COORY  < -80 [fy -75]
fin


Para BADGUY
dile 1
aD entero azar 10
de entero azar 360
iz entero azar 10
da "BADX entero CoORx
da "BADY entero coory
fin

Para BADGUY1
dile 2
ad entero azar 10
de entero azar 360
iz entero azar 10
da "BADX1 entero coorx
da "BADY1 entero coory
fin

Para BADGUY2
dile 3
ad entero azar 10
de entero azar 360
iz entero azar 10
da "BADX2 entero coorx
da "BADY2 entero coory
fin

Para COLLIDE 
dile 0
si (distancia (lista :BADX :BADY)) < 10 [BANG] 
si (distancia (lista :BADX1 :BADY1)) < 10 [BANG] 
si (distancia (lista :BADX2 :BADY2)) < 10 [BANG]
si colordebajo  = 10 [es "ganaste altotodo]
si colordebajo  = 4 [es "perdiste altotodo]


fin


Para BANG
tono 500 5
bt
es [OUCH!]
es [LO SIENTO MUCHO, CHOCASTE !]
REPITE 5[FCOLORF 24 ESPERA 3 FCOLORF 0]
altotodo
fin


Para NORTH :DIR
si :DIR = "8 [ad 5]
si :DIR = "4 [de 90 da "FACING 8]
si :DIR = "2 [de 90 da "FACING 4]
si :DIR = "6 [iz 90 da "FACING 8]
fin

Para EAST :DIR 
si :DIR = "8 [de 90 da "FACING 6]
si :DIR = "4 [de 90 da "FACING 8]
si :DIR = "2 [iz 90 da "FACING 6]
si :DIR = "6 [ad 5]
fin

Para WEST :DIR
si :DIR = "8 [iz 90 da "FACING 4]
si :DIR = "4 [ad 5]
si :DIR = "2 [de 90 da "FACING 4]
si :DIR = "6 [iz 90 da "FACING 8]
fin

Para SOUTH :DIR
si :DIR = "8 [de 90 da "FACING 6]
si :DIR = "4 [iz 90 da "FACING 2]
si :DIR = "2 [ad 5] 
si :DIR = "6 [de 90 da "FACING 2]

fin

Para PROCESSKEY :KEY
bT 
GOODGUY
COLLIDE
si :KEY = "Q [altotodo]
si :KEY = "P [IMPPANT]
si :KEY = "8 [NORTH :FACING]
si :KEY = "6 [EAST :FACING]
si :KEY = "4 [WEST :FACING]
si :KEY = "2 [SOUTH :FACING]
fin

Para GETKEY
si tecla? [PROCESSKEY leecar]
COLLIDE
BADGUY
BADGUY1
BADGUY2
GETKEY
fin

para laguna
sp fpos[45 -55]cp
repite 45 [ad 1 de 2]
repite 28 [ad 1 de 6]
repite 15 [ad 1 iz 6]
repite 40 [ad 1 de 5]
de 45 sp ad 10 
fcolor 10 cp pinta
fin
 
Para TODO
bt
rg
fcolor 7 pinta fcolor 1
laguna
bm
dile todas sp
BEGIN
SETUPGOOD
SETUPBAD
SETUPBAD1
SETUPBAD2
dile [1 2 ] cp fcolor 4
dile 3 cp fcolor 1
GETKEY
fin