To run the Gallery programs you will need
some new procedures in your Logo library.
For that, with each one of the following
procedures, do this:

Copy & Paste it into NotePad.
Save it at the procedure's name.
Put the saved files into Logolib directory.


-----------------------------
to 3d_frame ; draw "3D" frame
reset
setpc 7
sph -110 -110  0 fd 220 rt 90 fd 220
sph -109 -109  0 fd 218 rt 90 fd 218
sph -102 -102 90 fd 204 lt 90 fd 204
setpc 0
sph -110 -110 90 fd 220 lt 90 fd 220
sph -109 -109 90 fd 218 lt 90 fd 218
sph -102 -102  0 fd 204 rt 90 fd 204
sph 0 0 0 setfc 0 fill
end

bury "3d_frame
-----------------------------
to arcl :ang :rad ; draw "left" arc
test :ang>0
ift[lt .5 repeat  :ang[fd :rad*pi/180 lt 1]rt .5]
iff[rt .5 repeat -:ang[fd :rad*pi/180 rt 1]lt .5]
end

bury "arcl
-----------------------------
to arcr :ang :rad ; draw "right" arc
test :ang>0
ift[rt .5 repeat  :ang[fd :rad*pi/180 rt 1]lt .5]
iff[lt .5 repeat -:ang[fd :rad*pi/180 lt 1]rt .5]
end

bury "arcr
-----------------------------
to reset ; set/restore MSWLogo defaults
ht wrap ppt clearpalette
setlabelfont[[Arial] -16 0 0 700 0 0 0 177 3 2 1 42]
setactivearea[-500 -500 500 500]
setpc 0 setsc[192 192 192] setfloodcolor 4
setpensize[1 1] setscrunch 1 1
windowdelete "main
end

bury "reset
-----------------------------
to sp :x :y ; move to selected location
pu setxy :x :y pd
end

bury "sp
-----------------------------
to sph :x :y :head ; move to selected location & set heading
pu setxy :x :y pd
seth :head
end

bury "sph
-----------------------------
to sphc :x :y :head :col ; move to selected location, set heading & color
pu setxy :x :y pd
seth :head
setpc :col
end

bury "sphc
------------------------------