Pov-Ray 4.4.10 Text Object

Esta página pretende dar una idea de lo que se puede hacer directamente con Pov-Ray, en lo que respecta al texto.

Veremos como crear objetos de texto utilizando POV-Ray para resaltar las letras que en otra versiones tuvieron que ser construidas desde CSG o a través de una imagen blanca y negra de las letras, como un campo de altura, lo cual es un proceso laborioso, un método que era único y poco satisfactorio. Ahora, para Pov-Ray 3.0, se ha introducido un nueva primitiva a través de la cual se puede utilizar cualquier fuente TrueType para crear objetos de texto. Estos objetos pueden usarse en CSG, transformarse y ser factibles de que se le aplique texturas como cualquier otro objeto primitivo de Pov-Ray .

Crearemos un archivo llamado textdemo.pov y lo editaremos como se indica a continuación:

  #include "colors.inc"

  camera {
  location <0, 1, -10>
  look_at 0
  angle 35
  }

  light_source { <500,500,-1000> White }

  plane { y,0
  pigment { checker Green White }
  }

Ahora agregaremos el objeto de texto, para lo cual nosotros usaremos la fuente timrom.ttf y crearemos una palabra o frase para ser utilizada en POV-Ray. La sintaxis es muy simple. Primero y entre paréntesis va el nombre de fuente, en segundo lugar va la palabra o frase que va a ser rendida. Los dos números flotantes son los valores de el espesor y de compensación. El número flotante correspondiente al espesor que determina cuan gruesas son las letras. Los valores de .5 a 2 son los que mejor se adaptan para ésto. El valor de compensación influirá sobre la inclinación de las letras y se agregará a la kerning. Por ahora determinaremos un valor correspondiente a 0.

  text { ttf "timrom.ttf" "POV-RAY 3.0" 1, 0
  pigment { Red }
  }

Rendimos esto en primer lugar a baja resolución y notaremos que las letras están desviadas a la derecha de la pantalla. Esto es porque ellas se ponen suponiendo que la primer letra está en el órigen .
Para centrar el dato, nosotros necesitamos trasladarnos:

  text { ttf "timrom.ttf" "POV-RAY 3.0" 1, 0
  pigment { Red }
  translate -3*x
  }

tut01.jpg - 4,70 K

Ahora podemos jugar con algunos de los parámetros del objeto texto. Primero, trataremos de agregar espesor a ... 25!

  text { ttf "timrom.ttf" "POV-RAY 3.0" 25, 0
  pigment { Red }
  translate -2.25*x
  }

Ahora dejaremos el valor del espesor a 1 y trataremos con un valor diferente de compensación. Cambie el número flotante de 0 a 0.1 y rindalo nuevamente.

tut02.jpg - 4,89 K

Las letras se desvían hacia arriba!. Y será posible obtener otros efectos a través del cambio de este valor, por ejemplo 0.1*x, 0.1*y y 0.1*z (donde no hay desplazamiento).

Por supuesto que podremos dar a nuestras letras una textura adecuada a nuestros intereses, a la vez de agregar un cielo y un piso que nos guste:

  #include "colors.inc"

  camera {
  location <-5,.15,-2>
  look_at <.3,.2,1>
  angle 35
  }

  light_source { <500,500,-1000> White }

  plane { y,0
    texture {
        pigment { SeaGreen }
        finish { reflection .35 specular 1 }
        normal { ripples .35 turbulence .5
      scale .25 }
      }
  }

  text { ttf "timrom.ttf" "POV-RAY 3.0" 25, 0.1*y
    pigment { BrightGold }
    finish { reflection .25 specular 1 }
    translate -3*x
  }

  #include "skies.inc"

  sky_sphere { S_Cloud5 }

tut03.jpg - 7,58 K

 

 

Pagina Principal Tutores Utilitarios Galería Novedades El Autor 

Página elaborada por
Juan Carlos Marquez
juanm@adinet.com.uy