Este es un ejercicio que podrán resolver utilizando MS-Excel. Se le brinda al alumno el temario, una imagen de la pantalla de la computadora, y finalmente las fórmulas para que las ingrese.
Una sugerencia: traten primero de resolver solos el ejercicio, y luego pueden comparar con el resultado que propongo.
Ejercicio 1
Este ejercicio consiste en desarrollar el flujo de fondos de un pequeño proyecto de inversión.
Los datos básicos son los siguientes:
Cantidad de productos a vender por
año: 1000
Precio de venta unitario: 9
Costo fijo anual 2000
Costo variable expresado como % de las ventas 40%
Inversión en capital de trabajo
500
Inversión en activo fijo
4000
Valor de recupero del activo fijo 800
Tasa de impuestos a las ganancias 30%
Tasa de descuento 10%
En base a estos datos Uds. deberán:
1. Calcular el flujo de fondos del
proyecto
2. Calcular el período de recuperación de la inversión
3. Calcular el período de recuperación de la inversión descontado
4. Calcular el valor actual neto
5. Calcular la tasa interna de retorno
Ayuda
Para desarrollar el ejercicio pueden utilizar esta planilla:
|
|
A |
B |
C |
D |
E |
|
1 |
Cantidad |
1000 |
|
|
|
|
2 |
Precio |
9 |
|
|
|
|
3 |
C Fijo |
2000 |
|
|
|
|
4 |
C Variable |
40% |
|
|
|
|
5 |
Inv CT |
500 |
|
|
|
|
6 |
Inv AF |
4000 |
|
|
|
|
7 |
Recup AF |
800 |
|
|
|
|
8 |
Impuestos |
30% |
|
|
|
|
9 |
Tasa Desc |
10% |
|
|
|
|
10 |
|
|
|
|
|
|
11 |
Flujo Fondos |
0 |
1 |
2 |
3 |
|
12 |
Ingresos |
|
|
|
|
|
13 |
C Variable |
|
|
|
|
|
14 |
C Fijo |
|
|
|
|
|
15 |
Subtotal |
|
|
|
|
|
16 |
Impuestos |
|
|
|
|
|
17 |
Subtotal |
|
|
|
|
|
18 |
Inv CT |
|
|
|
|
|
19 |
Inv AF |
|
|
|
|
|
20 |
Recup CT |
|
|
|
|
|
21 |
Recup AF |
|
|
|
|
|
22 |
Total |
|
|
|
|
|
23 |
|
|
|
|
|
|
24 |
|
|
|
|
|
|
25 |
PRI Simple |
0 |
1 |
2 |
3 |
|
26 |
|
|
|
|
|
|
27 |
Acumulado |
|
|
|
|
|
28 |
Recupero |
|
|
|
|
|
29 |
|
|
|
|
|
|
30 |
|
|
|
|
|
|
31 |
PRI Des |
0 |
1 |
2 |
3 |
|
32 |
|
|
|
|
|
|
33 |
VA |
|
|
|
|
|
34 |
Acumulado |
|
|
|
|
|
35 |
Recupero |
|
|
|
|
|
36 |
|
|
|
|
|
|
37 |
|
|
|
|
|
|
38 |
VAN |
0 |
1 |
2 |
3 |
|
39 |
|
|
|
|
|
|
40 |
VAN |
|
|
|
|
|
41 |
|
|
|
|
|
|
42 |
VF |
|
|
|
|
|
43 |
Acumulado |
|
|
|
|
|
44 |
VA del VF |
|
|
|
|
|
45 |
|
|
|
|
|
|
46 |
|
|
|
|
|
|
47 |
TIR |
0 |
1 |
2 |
3 |
|
48 |
|
|
|
|
|
|
49 |
TIR |
|
|
|
|
|
50 |
|
|
|
|
|
Aquí están las fórmulas línea por línea que deberían ingresar para obtener el resultado final (estas fórmulas no son taxativas):
C12. =$B$1*$B$2
D12. =$B$1*$B$2
E12. =$B$1*$B$2
C13. =-C12*$B$4
D13. =-D12*$B$4
E13. =-E12*$B$4
C14. =-$B$3
D14. =-$B$3
E14. =-$B$3
C15. =SUMA(C12:C14)
D15. =SUMA(D12:D14)
E15. =SUMA(E12:E14)
C16. =-C15*$B$8
D16. =-D15*$B$8
E16. =-E15*$B$8
C17. =C16+C15
D17. =D16+D15
E17. =E16+E15
B18. =-B5
B19. =-B6
E20. =+B5
E21. =+B7
B22. =SUMA(B17:B21)
C22. =SUMA(C17:C21)
D22. =SUMA(D17:D21)
E22. =SUMA(E17:E21)
A26. =A$22
B26. =B$22
C26. =C$22
D26. =D$22
E26. =E$22
B27. =B26
C27. =B27+C26
D27. =C27+D26
E27. =D27+E26
C28. =SI(Y(B27<0;C27>0);C25+ABS(B27/C26);"")
D28. =SI(Y(C27<0;D27>0);D25+ABS(C27/D26);"")
E28. =SI(Y(D27<0;E27>0);E25+ABS(D27/E26);"")
A32. =A$22
B32. =B$22
C32. =C$22
D32. =D$22
E32. =E$22
B33. =VA($B$9;B31;;-B32)
C33. =VA($B$9;C31;;-C32)
D33. =VA($B$9;D31;;-D32)
E33. =VA($B$9;E31;;-E32)
B34. =B33
C34. =B34+C33
D34. =C34+D33
E34. =D34+E33
B35. =MIN(C35:E35)
C35. =SI(Y(B34<0;C34>0);C31+ABS(B34/C33);"")
D35. =SI(Y(C34<0;D34>0);D31+ABS(C34/D33);"")
E35. =SI(Y(D34<0;E34>0);E31+ABS(D34/E33);"")
A39. =A$22
B39. =B$22
C39. =C$22
D39. =D$22
E39. =E$22
B40. =VNA($B$9;C39:E39)+B39
B42. =VF($B$9;3-B38;;-B39)
C42. =VF($B$9;3-C38;;-C39)
D42. =VF($B$9;3-D38;;-D39)
E42. =VF($B$9;3-E38;;-E39)
B43. =B42
C43. =B43+C42
D43. =C43+D42
E43. =D43+E42
B44. =VA($B$9;3;;-E43)
A48. =A$22
B48. =B$22
C48. =C$22
D48. =D$22
E48. =E$22
B49. =TIR(B48:E48)
Al ingresar las fórmulas, es importante que entiendan bien cómo funciona Excel, para obtener el máximo provecho.
jquinteros@herrera.unt.edu.**
-
cpnquinteros@yahoo.com.** -
cpnquinteros@arnet.com.**
(reemplazar ** por ar;
es para eludir virus de correo electrónico)
Volver al Índice Volver Arriba