EXPOSICION DE EDUARDO OLAZ

El otro día en el grupo es.compbd.ms-access solicitaron un método para
definir por código el tamaño de la ventana de Access.
Como creo que a varios de vosotros os podrá interesar, adjunto el código que
le pasé.

Este código permite definir el tamaño y la posición de la ventana de Access.

___________________________________________

Option Explicit

    Const con_Abajo = 1
    Const con_Arriba = 0
    Const con_ArribaMas = -2
    Const con_ArribaTotal = -1

    Const conVentanaConMarco As Long = &H20
    Const conVentanaNoCambiarPosicion As Long = &H2
    Const conVentanaNoCambiarTamaño As Long = &H1

Declare Function SetWindowPos _
                Lib "user32" _
                ( _
                ByVal hwnd As Long, _
                ByVal hWndInsertAfter As Long, _
                ByVal x As Long, _
                ByVal y As Long, _
                ByVal cx As Long, _
                ByVal cy As Long, _
                ByVal wFlags As Long) _
                As Long

Public Sub TamañoVentanaAccess( _
                ByVal Ancho As Long, _
                Alto As Long)
    Dim lngManejador As Long
    Dim lngResultado As Long
    ' Cambia la ventana del programa Access
    ' al tamaño en pixeles definido por
    ' los parámetros Ancho y Alto
    ' Eduardo Olaz - eduardo@olaz.net 20/10/02
    lngManejador = Application.hWndAccessApp
    lngResultado = SetWindowPos( _
                lngManejador, _
                con_ArribaMas, _
                0, 0, _
                Ancho, _
                Alto, _
                conVentanaNoCambiarPosicion)
End Sub

Public Sub PosicionVentanaAccess( _
                ByVal Izquierda As Long, _
                Arriba As Long)
    Dim lngManejador As Long
    Dim lngResultado As Long
    ' Cambia la posición de la ventana
    ' del programa Access a la definida por
    ' los parámetros Izquierda y Arriba
    ' Eduardo Olaz - eduardo@olaz.net 20/10/02
    lngManejador = Application.hWndAccessApp
    lngResultado = SetWindowPos( _
                lngManejador, _
                con_ArribaMas, _
                Izquierda, _
                Arriba, _
                0, 0, _
                conVentanaNoCambiarTamaño)
End Sub
___________________________________________

    Source: geocities.com/es/ensolva/Descargas/Documentos

               ( geocities.com/es/ensolva/Descargas)                   ( geocities.com/es/ensolva)                   ( geocities.com/es)