Claves primarias, claves foráneas, índices

En la teoría de bases de datos, se llama clave primaria a un campo, o a una combinación de campos, que identifica en forma única a cada registro, y una clave foránea es una referencia, en una tabla, a la clave primaria de otra tabla. Por ejemplo, en una factura necesitamos identificar para qué cliente se ha hecho la factura.

Por ejemplo, para una tabla de clientes se podría usar, como clave primaria, una de las siguientes opciones:

La cédula de identidad del cliente.
La combinación de nombre y apellido. Esto es dudoso, ya que un dos clientes pueden tener el mismo nombre y el mismo apellido.
Un código de cliente, asignado por la empresa.

Sin embargo, lo más recomendable es utilizar un número que nunca verá el usuario final. Para este fin, se necesita un número secuencial. Esto nos trae numerosas ventajas, entre otras:

Se simplifican las claves foráneas y las relaciones entre las tablas. Por ejemplo, si para identificar a un cliente utilizamos la combinación de nombre y apellido, también necesitamos el nombre y el apellido del cliente en la factura, para identificar al cliente.
Se ahorra espacio, ya que un campo de tipo Integer (entero) sólo utiliza 4 bytes (sin embargo, permite números hasta 2 mil millones). Se puede argumentar que se necesita un campo más para la clave primaria; pero se ahorra espacio en las claves foráneas en otras tablas.
El acceso a los datos es más rápido. Esto está directamente relacionado con el hecho de que los campos de tipo Integer (y sus índices correspondientes) son más pequeños.
El usuario puede cambiar los códigos, sin que se tengan que "propagar" los cambios a otras tablas.

También hay algunas desventajas; sobre todo, la programación se hace más complicada en algunos casos. Pero he visto en la práctica que es un sacrificio que vale la pena.

Ahora, explicaré los detalles de cómo implementar estas claves "internas". Desafortunadamente, en Visual FoxPro no se puede simplemente marcar un campo como "auto-incrementado" (como se lo haría en Access), pero no es muy complicado lograr lo mismo en Visual FoxPro.

Para guardar los números secuenciales (y así saber cuál es el siguiente número que se debe asignar a cada nuevo registro), se crea una tabla que se llama "serialnumber", con dos campos: "sequence", tipo Character(30), y "nextnum", tipo Integer. Es conveniente (pero no urgente) que la tabla sea parte de una base de datos (sólo así puede participar en transacciones, lo cual permite anular cambios).
Para la clave primaria, se utiliza un campo de tipo Integer (ver Nuevos tipos de datos). Por ejemplo, en la tabla "cliente", se puede tener un campo que también se llama "cliente", de tipo Integer.
En ese campo de clave primaria, se entra a "Default", y se escribe la siguiente expresión: serialnumber("cliente").
Esto invocará una función "serialnumber". Yo prefiero almacenar la función en los procedimientos almacenados de la base de datos. La función es:

**********************************************************************
FUNCTION SERIALNUMBER(tnSequence)
* Conseguir número secuencial. Usado para generar claves primarias.
local lnSelect
lnSelect = select()
if used("serialnumber")
   select serialnumber
else
   select 0
use serialnumber
endif
set order to "sequence"
seek padr(tnSequence, len(sequence))
if not found()
   append blank
   replace sequence with tnSequence, nextnum with 1
endif
local lnReturnValue
if lock()
   lnReturnValue = nextnum
   replace nextnum with nextnum + 1
else
   lnReturnValue = -1
endif
unlock
select (lnSelect)
return lnReturnValue

Para definir una clave primaria en una tabla, se tiene que crear un índice con una expresión que tiene que ser única. Luego, se define el índice como clave primaria ("Primary"). Esto se lo hace directamente en la definición de la tabla (modify structure). Por ejemplo, en la tabla cliente, se crea un índice por el campo cliente. La forma más rápida de hacer ésto es indicar, en la misma lista de campos, que se quiere tener un índice sobre ese campo (siempre debe ser "ascending"). Luego, en la página de índices se lo marca como "Primary".

Se puede asegurar que otras combinaciones de campos sean únicas. Sólo puede haber una clave primaria en una tabla, pero se pueden marcar otros índices como "Candidate". En otros sistemas de base de datos, esto se llamaría "Unique"; desafortunadamente, en FoxPro esta palabra ya ha sido reservado para algo distinto. Recomiendo no utilizar nunca índices del tipo "Unique" en Visual FoxPro; lo que estos índices logran, mejor se puede lograr con otros métodos. Digamos que Visual FoxPro incluye índices de tipo "Unique" por mantener la compatibilidad con FoxPro.

Si se quiere garantizar unicidad, puede haber un problema con registros borrados: el usuario borra un cliente, digamos que tiene el código (campo cod_cliente) "X1", luego agrega otro registro e intenta poner el mismo código. Visual FoxPro dirá que el registro ya existe. Se puede solucionar esto eliminando permanente el registro borrado (con la orden PACK), pero esto no es muy práctico. Es mejor crear el índice filtrado, con la condición: NOT DELETED().

Volver a: Visual FoxPro | Página Principal de Hilmar Zonneveld