10 REM REVTCBP.BAS
20 REM THIS PROGRAM REVERSE ENGINEERS A TOP COUPLED BAND PASS FILTER TO
30 REM OBTAIN THE LOW PASS PROTOTYPE VALUES
40 CLS : PRINT"TO CONVERT A TOP COUPLED DESIGN TO THE LOPASS PROTOTYPE:"
50 PRINT
60 DIM C(10),CC(10,10),A(10),LPC(10)
70 PI=3.1415927#
80 PRINT"INPUT THE COUPLING CAPS FIRST, THEN THE SHUNT CAPS"
90 INPUT"HOW MANY POLES ";N
92 INPUT"WILL YOU ENTER THE CENTER FREQUENCY AND BANDWIDTH (1) OR F1,F2 (2)";Y
94 ON Y GOTO 100, 112
100 INPUT"CENTER FREQUENCY IN HZ = ";F0
110 INPUT"BANDWIDTH IN HZ = ";BW :GOTO 129
112 INPUT"LOWER FREQUENCY (F1) IN HZ";F1
114 INPUT"UPPER FREQUENCY (F2) IN HZ";F2
116 F0=(F1*F2)^.5:BW=F2-F1
129 Q=F0/BW
130 INPUT"SOURCE RESISTANCE = ";RS
140 FOR J=1 TO N-1
150 PRINT"COUPLING CAP ";J;",";J+1;" = ";
160 INPUT C
170 CC(J,J+1)=C*2*PI*F0*RS
180 PRINT"COUPLING CAP ";J;",";J+1;" = ";CC(J,J+1)
190 NEXT J
200 FOR J=1 TO N
210 PRINT"SHUNT CAP #";J;" =";
220 INPUT C
230 C(J)=C*2*PI*F0*RS
240 NEXT J
250 A(1)=C(1)+CC(1,2): C(1)=A(1)
260 C(N)=C(N)+CC(N-1,N)
270 FOR J=2 TO N-1
280 C(J)=C(J)+CC(J-1,J)+CC(J,J+1)
290 NEXT J
300 REM PRINT:PRINT"NORMALIZED VALUES"
310 REM FOR J=1 TO N:PRINT "C(";J;") =";C(J):NEXT
320 FOR J=2 TO N
330 A(J)=C(J-1)*C(J)/(A(J-1)*CC(J-1,J)^2)
340 NEXT J
350 REM PRINT: PRINT"PRELIMINARY DESIGN VALUES"
360 REM PRINT"SECTION","ELEMENT VALUE"
370 REM FOR J=1 TO N:PRINT J,A(J):NEXT J
380 FOR J=1 TO N
390 LPC(J)=A(J)/2/PI/Q
400 NEXT J
410 PRINT:PRINT"LOW PASS PROTOTYPE VALUES"
420 FOR J=1 TO N STEP 2
430 PRINT"C";J;" =";LPC(J)
440 IF J=N THEN 470
450 PRINT"L";J;" =";LPC(J+1)
460 NEXT J
470 INPUT"FOR HARDCOPY USE PRINT SCREEN KEY",Y$:CHAIN "FILTMENU"
480 END
(
geocities.com/russlk)