; Sample Cyborg.script

ON INCHAT 
{
; expressive prop changes - in response to what others say
	{ "pitchfork" DONPROP { DOFFPROP } 120 ALARMEXEC } CHATSTR "you devil" == IF
	{ "Halo" DONPROP { DOFFPROP } 120 ALARMEXEC } CHATSTR "you angel" == IF
	{ "Lightbulb" DONPROP { DOFFPROP } 120 ALARMEXEC } CHATSTR "you genius" == IF
	{ "Fez" DONPROP { DOFFPROP } 120 ALARMEXEC } CHATSTR "you shriner" == IF
	{ "Beanie" DONPROP { DOFFPROP } 120 ALARMEXEC } CHATSTR "you geek" == IF
	{

; this is your FINGER information - replace the stuff in quotes with 
; information about yourself.
		"^\x0d"
		"\x0d" +
		WHOCHAT PRIVATEMSG
	} CHATSTR "finger" == CHATSTR ";finger" == OR 
	  WHOCHAT WHOME == NOT AND IF
}

ON OUTCHAT 
{
; more expressive prop changes (in response to what YOU say)
	{
		{ "Halo" DONPROP { DOFFPROP } 120 ALARMEXEC } 30 ALARMEXEC
	} CHATSTR "who me.$" GREPSTR IF


	{
		{ "Lightbulb" DONPROP { DOFFPROP } 120 ALARMEXEC } 30 ALARMEXEC
	} CHATSTR "a.* idea" SUBSTR IF


; Zap somebody by positioning the mouse and then say "zap"
	{ "!)no Zap!" MOUSEPOS SAYAT
	   255 0 0 PENCOLOR 2 PENSIZE 
	   POSX POSY MOUSEPOS LINE 
	   PAINTUNDO
	  "" CHATSTR =
	} CHATSTR "zap" == IF


; clean the room by saying "clean"
	{
       CLEARLOOSEPROPS
       PAINTCLEAR
	} CHATSTR "clean" == IF


; spoof somebody by positioning the mouse on their mouth and then type "msay blah blah"
	{ "$1" GREPSUB chatter =
	  chatter MOUSEPOS SAYAT
	  "" CHATSTR =
	} CHATSTR "^msay (.*)$" GREPSTR IF

; give Joe Beer
	{ "$1" GREPSUB who = "$2" GREPSUB prop =
	  prop who WHOPOS ADDLOOSEPROP
	} CHATSTR "^give (.*) (.*)$" GREPSTR IF
}

ON SIGNON
{
	"@64,64 !It's " USERNAME + SAY
	1 MACRO
}

    Source: geocities.com/siliconvalley/network/8524/scripts

               ( geocities.com/siliconvalley/network/8524)                   ( geocities.com/siliconvalley/network)                   ( geocities.com/siliconvalley)