Utilização da Grade Vinculada aos dados: DbGrid.

 

Conteúdo

• Introdução.
• Utilização e Configuração.
• Projeto - Controle Financeiro.
• Controle Financeiro - Definição de tabelas.
• Controle Financeiro - Interface com o usuário.
• Controle Financeiro - Código do projeto.
• DbGrid - Dicas e Truques

Introdução.

A Grade Vinculada aos dados - DbGrid  oferece um meio para visualizar vários 
registros ao mesmo tempo. Assemelha-se ao commando Browse usado no Clipper/FoxPro
e ao modo tabela do Access.

O seu primo pobre no VB seria o controle Grid, e, apenas para dimensionar a dife-
rença ,o Grid está limitado a  16352 linhas e 5450 colunas no Dbgrid a 
quantidade de linhas esta condicionada aos recursos do  sistema e a 1700 colunas,
sem contar que o desempenho do Dbgrid e bem superior ao do Grid.

Enquanto o Grid precisa ser configurado quase que totalmente via código, para usar 
o Dbgrid basta arrastar o ícone do Controle para o seu formulário e definir a 
propriedade DataSource para identificar o controle de dados que contém os dados 
que você quer exibir, e pronto, a grade exibe todos os campos dos registros do 
recordset.

Nota:Para preservar recursos do sistema use uma instrução SQL na propriedade 
     Recordsource do controle de dados que o DbGrid irá utilizar.

Conteúdo

Utilização e configuração.

Vejamos passo a passo como utilizar o Dbgrid com o controle de dados vinculados 
- Data Control.

fig1.

De início selecione o objeto controle de dados na Toolbox do Visual Basic e acrescente-o ao seu formulário.(Fig.1)

fig.4

A seguir selecione o ícone  do DBGrid na ToolBox e arreste-o até o seu form dimensionando como na fig.4. ao lado.

fig.5

Finalmente defina a propriedade DataSource vinculado-a ao controle de dados configurado anteriormente.fig.5.

fig.6

Projeto - Controle Financeiro..

-objetivo:  Controlar a  movimentação de contas bancárias.

-Constituição: 

• Um formulário MDI para o menu de opções com botões de ícones.
• Um formulário para cadastrar : Clientes , Contas , Transações.
• Um formulário para visualizar a movimentação de determinada conta.
• Um formulário para incluir dados.
• Um formulário para excluir dados.
• Um formulário para alterar dados.
• Um módulo para código utilizado por toda a aplicação.

fig 1.0

Neste formulário temos os seguintes controles: -1 controle SSPanel -5 botões SSCommand Além disso temos um menu feito no Editor de Menus do Visual  Basic.

Private Sub SSCommand1_Click(Index As Integer)

   Select Case Index
      Case 0 'botão 1 - Cadastramentos (por sua conta)
      Case 1 'Gerencia movimento           
         frmtransa.Show
      Case 2 'Relatórios 
      Case 3 'Ajuda
      Case 4 'Sair da aplicação
         end
   End Select   
        
End Sub

Controle Financeiro - Definição das tabelas..

- BANCO.MDB   - será o banco de dados do nosso sistema.
- tblcli      - Tabela de cadastro dos clientes.
- tblcontas   - Tabela de cadastro das contas a controlar.
- tblcodtrans - Tabela de cadastro dos códigos das transações realizadas.
- tbltrans    - Tabela onde será registrada toda a transação realizada.

Vejamos agora a definição dos campos de cada tabela e a criação do banco de dados.

1-Crie o seu banco de dados utilizando o Data Manager ou use
 o Microsoft Access e grave-o com o nome de BANCO.MDB.

2-Crie uma tabela com o nome de tblcli com a seguinte estrutura:
  ----------------------------------------------------
   Nome do Campo       Tipo de Dados        Tamanho
  ----------------------------------------------------
    COD_CLI              LONG INTEGER(*)        
    DES_CLI              CARACTER              30
  ---------------------------------------------------- 
  (*)Como cada cliente deve ter um codigo único  garantindo assim a exata 
  identificação do mesmo, defina o tipo de dados para o campo código como
  LONG INTEGER , e ative o atributo Counter e a opção Required.

3-Crie uma tabela com o nome de tblcontas com a seguinte estrutura:
  ----------------------------------------------------
   Nome do Campo       Tipo de Dados        Tamanho
  ----------------------------------------------------
    COD_CLI             LONG 
    COD_CONTA           LONG                   30
    DES_CONTA           TEXT                   30      
  ---------------------------------------------------- 
   
-Defina um índice para os campos cod_cli e cod_conta com o nome de cliconta
 e com as seguintes propriedades: Unique, Primary index , Required. 

4-Crie uma tabela com o nome de tblcodtrans com a seguinte estrutura:
  ----------------------------------------------------
   Nome do Campo       Tipo de Dados        Tamanho
  ----------------------------------------------------
    COD_TRAN            LONG 
    DES_TRAN            TEXT                  30
  ---------------------------------------------------- 
  
-Defina um índice para o campo COD_TRANS  e indique-o como chave primária
  
5-Finalmente , Crie uma tabela com o nome de tblcodtrans com a estrutura:
  ----------------------------------------------------
   Nome do Campo       Tipo de Dados        Tamanho
  ----------------------------------------------------
    COD_LANCA           LONG INTEGER(*)
    COD_TRANS           LONG 
    COD_CLI             LONG
    COD_CONTA           LONG
    DATA_TRANS          DATE/TIME
    LANCAMENTO          CURRENCY
    SALDO               CURRENCY
    NU_DCTO             TEXT                 15
    OBS_TRANS           TEXT                 30
  ---------------------------------------------------- 
(*)Como cada lancamento deve ter um codigo único  garantindo assim sua exata 
  identificação , defina o tipo de dados para o campo cod_lanca
  LONG INTEGER , e ative o atributo Counter e a opção Required.
 
-Defina os seguintes índices para esta tabela:

  ----------------------------------
   nome do indice       composição      
  ----------------------------------    
  - PrimaryKey          cod_lanca      índice - chave primária (já definido) 
  ----------------------------------     
  - datatrans           data_trans     índice - datatrans por data de transação
  ----------------------------------

Controle Financeiro - Interface com o usuário.

- frmtrans - Formulário que gerencia a movimentação das contas
- frmexcl  - Formulário para exclusão de lançamentos
- frmincl  - Formulário para incluir lançamentos
- frmalt   - Formulário para efetuar alterações nos lancamentos efetuados

1-O formulário frmtrans é o formulário principal de nossa aplicação , pois
através dele iremos gerenciar a movimentação das contas. Ele terá o aspecto da 
fig1.0 abaixo:

fig 1.0

fig 2.0

fig 3.0

Conteúdo

Controle Financeiro - Código do projeto.

-Código do formulário de menu:frmmenu

Botões de Comando do Menu.

Private Sub SSCommand1_Click(Index As Integer)
   select case index
     case 0
     case 1 'frmtransa
       frmtransa.Show 
     case 2 
     case 3
     case 4 'sair
       end
   end select
End Sub



-Código do formulário das transações:frmtransa


-Caixa de combinação cliente

Private Sub cbocliente_Click()
  If cbocliente.Text < > "" Then
     Dim sql_tmp As String
     sql_tmp = "SELECT * FROM tblcontas WHERE tblcontas.cod_cli=" & cbocliente.ItemData(cbocliente.ListIndex)
     enche_combo cboconta, sql_tmp, "cod_conta", "cod_cli"
  End If
End Sub


-caixa de combinação conta

Private Sub cboconta_Click()
  If cboconta.Text < > "" Then
      Dim arqtemp As Recordset
      Set arqtemp = db.OpenRecordset("tblcontas", dbOpenTable)
      arqtemp.Index = "codconta"
      arqtemp.Seek "=", Val(cboconta.Text)
      Label6.Caption = arqtemp("desc_conta")
      arqtemp.Close
      Maskini.SetFocus
  End If
End Sub


-Código dos botões Incluir, Excluir, Alterar e Sair

Private Sub Command1_Click(Index As Integer)
    Dim msg As String
   
    Set tabela = db.OpenRecordset("tbltrans", dbOpenTable)
    tabela.Index = "cod_conta"
         
    Select Case Index
    Case 0 'incluir
         alterareg = False
         frmtrans_i.Show 1
    Case 1  'excluir
         frmexcl.Show 1
         data2.Refresh
    Case 2 'alterar
         if dbgrid1.columns(0) < > "" then 
            tabela.Seek "=", DBGrid1.Columns(0)
         else
            msgbox "Selecione um lancamento a alterar ! "
            exit sub
         endif
         alterareg = True
         frmtrans_i.Show 1
    Case 3
        Unload Me
        Exit Sub
    End Select
    
    atualiza_grid (sql)
    Data2.Refresh

End Sub


-Código do botão Processar

Private Sub Command2_Click()
  
  Dim msg As String
  Dim x As Integer
  
  '------checa selecao de cliente/conta--
  If cbocliente.ListIndex = -1 Then
    msg = "Selecione um cliente !"
    MsgBox msg, vbExclamation
    cbocliente.SetFocus
    Exit Sub
  End If
  If cboconta.ListIndex = -1 Then
    msg = "Selecione uma conta !"
    MsgBox msg, vbExclamation
    cboconta.SetFocus
    Exit Sub
  End If
    
  '-- atribui cliente/conta as variaveis publicas
  Cliente = cbocliente.ItemData(cbocliente.ListIndex)
  conta = cboconta.Text
  
  '--habilita botões de comandos--
  For x = 0 To 2
    Command1(x).Enabled = True
  Next
  
  '-- estabelece consulta SQL ------
  sql = "SELECT data_trans, cod_trans, lancamento, nu_dcto, saldo, obs_trans  FROM tbltrans"
  sql = sql & " WHERE cod_cli=" & cbocliente.ItemData(cbocliente.ListIndex)
  sql = sql & " AND cod_conta=" & cboconta.Text
  
  '---------define tipo da transacao para consulta--
  If cbotipo.ListIndex < > -1 Then
      sql = sql & " AND cod_trans=" & cbotipo.ItemData(cbotipo.ListIndex)
   End If
  
  '---verifica data inicial/final e define período-----
  If Maskini < > "  /  /  " And maskfim < > "  /  /  " Then
    If Not IsDate(Maskini) Then
      msg = "Data inicial invalida"
      Maskini.SetFocus
      MsgBox msg, vbExclamation
      Exit Sub
    ElseIf Not IsDate(maskfim) Then
      msg = "Data final inválida "
      maskfim.SetFocus
      MsgBox msg, vbExclamation
      Exit Sub
    End If
     sql = sql & " AND data_trans >= " & "#" & Format((Maskini), "mm/dd/yy") & "#"
     sql = sql & " AND data_trans <= " & "#" & Format((maskfim), "mm/dd/yy") & "#"
  End If
  
  '-----atualiaza Recordsource-------
  sql = sql & " ORDER BY data_trans"
  Data2.RecordSource = sql
  atualiza_grid (sql)
  Data2.Refresh

End Sub


-Código de carga do formulário

Private Sub Form_Load()
  Dim x As Integer
  
  '-------define tamanho do form----
  Me.Width = 8295
  Me.Height = 5595
  
  '-- desabilita botões de comando
  For x = 0 To 2
    Command1(x).Enabled = False
  Next

  '---- abre tabela / e define índice ativo---
  'Set tabela = db.OpenRecordset("tbltrans", dbOpenTable)
  'tabela.Index = "clicndtr"
  
  '----configura data control---
  Data2.DatabaseName = App.Path & "\joias.mdb"
  Data2.RecordSource = "SELECT * FROM tbltrans WHERE cod_trans = Null"
  
  '---------formata grid--------------------
  DBGrid1.Columns(0).Width = 900
  DBGrid1.Columns(1).Width = 950
  DBGrid1.Columns(2).Width = 925
  DBGrid1.Columns(3).Width = 2200
  DBGrid1.Columns(4).Width = 1300
  DBGrid1.Columns(5).Width = 1300
  dbgrid1.columns(6).width = 1300
  
  '----------atualiza o grid-------------------
  Data2.Refresh
  
  '-------atualiza combobox  cliente ------------------
  enche_combo cbocliente, "tblcli", "des_cli", "cod_cli"
  enche_combo cbotipo, "tblcodtrans", "des_tran", "cod_tran"
  '----------------------------------------------
 
 End Sub


-Código da função que atualiza o Grid

Public Sub atualiza_grid(sql As String)
  Dim credito, debito As Currency
  Dim saldo_atu As Currency
  Dim arqtemp As Recordset
  saldo_atu = 0
  
  '---------------------------------------------
  Set arqtemp = db.OpenRecordset(sql, dbOpenDynaset)
  '---------------------------------------------
  If arqtemp.EOF Then
    MsgBox "Não há dados no arquivo !", vbExclamation
    arqtemp.Close
    Exit Sub
  End If
  arqtemp.MoveFirst
  Do
    credito = 0
    debito = 0
    If Not IsNull(arqtemp![lancamento]) Then
        If arqtemp![lancamento] > 0 Then
          credito = arqtemp![lancamento]
        Else
          debito = arqtemp![lancamento]
        End If
    Else
        credito = 0
        debito = 0
    End If
    saldo_atu = credito + debito + saldo_atu
    arqtemp.Edit
    arqtemp![saldo] = saldo_atu
    arqtemp.Update
    arqtemp.MoveNext
  Loop While Not arqtemp.EOF
  arqtemp.Close
End Sub


Código do formulário para incluir/alterar dados: Frmincl


Código dos botões Gravar, Cancelar e Sair 

Private Sub Command1_Click(Index As Integer)
    Select Case Index
    Case 0 'gravar
        grava_recs
        tabela.Update
        If alterareg Then
            Unload Me
            Exit Sub
        End If
        tabela.AddNew
        maskdata.SetFocus
    Case 1 'cancelar
        MsgBox "Atenção , as informações não foram gravadas ! "
        If alterareg Then
            Unload Me
            Exit Sub
        End If
        clear_controls
        maskdata.SetFocus
    Case 2 'sair
        Unload Me
    End Select
End Sub


Código de rotina de gravação 
Código do botão de opção Antes de

Private Sub Option1_Click()
    If Option1.Value = True Then
        Label2.Visible = False
        Text1.Visible = False
    End If
    Text2.SetFocus
End Sub


Código do botão de opção A Partir de
Private Sub Option2_Click()
    If Option2.Value = True Then
        Label2.Visible = False
        Text1.Visible = False
    End If
    Text2.SetFocus
End Sub



Código do botão de opção No período de

Private Sub Option3_Click()
    If Option3.Value = True Then
        Label2.Visible = True
        Text1.Visible = True
    End If
    Text2.SetFocus
End Sub


Código do modulo financa.bas


Código do seção general declarations

Option Explicit
Public area As Workspace
Public db As Database
Public tabela As Recordset
Public consulta As QueryDef
Public alterareg As Boolean
Public sql As String
Public cliente As Long
Public conta As Long


Código de Sub Main

Sub main()
   'define area ativa e abre arquivo de dados
   Set area = DBEngine.Workspaces(0)
   Set db = area.OpenDatabase(App.Path & "\banco.mdb")
   'mostra formulário de menu
   frmmenu.Show
End Sub


Código da função que preenche as combobox

Public Sub enche_combo(combo As Control, data As String, campo As String, indice As String)

'-- cria variável recordset temporária
Dim arqtemp As Recordset
'-----limpa combo
combo.Clear
'-----abre tabela como Snapshot
Set arqtemp = db.OpenRecordset(data, dbOpenSnapshot)
'--inicia loop através da tabela---
Do Until arqtemp.EOF
    combo.AddItem arqtemp(campo)
    combo.ItemData(combo.NewIndex) = arqtemp(indice)
    arqtemp.MoveNext
Loop
'---fecha recordset e não seleciona nada na combo
arqtemp.Close
combo.ListIndex = -1

End Sub

DbGrid - Dicas e Truques.

1-Tornando uma coluna invisível

DbGrid1.columns(i).visible= False