STRPDM.COM

     /*--------------------------------------------------------------*/
     /*  PROGRAM NAME       : CVTODC1C                               */
     /*  PROGRAM DESCRIPTION: COPY ALL REPORTS IN *CURRENT USERS SPLF*/
     /*                       TO AN AS/400 FOLDER AS A TEXT DOCUMENT.*/
     /*                                                              */
     /*  CREATED BY         :                                        */
     /*                                                              */
     /*  CREATE DATE        :                                        */
     /*--------------------------------------------------------------*/
     /*  MODIFICATIONS:                                              */
     /*--------------------------------------------------------------*/
     /*  MODIFIED BY        :                                        */
     /*  MODIFY DATE        :                                        */
     /*  MODIFICATION       :                                        */
     /*--------------------------------------------------------------*/

 

             PGM

 

             DCL        VAR(&FILET) TYPE(*CHAR) LEN(12)
             DCL        VAR(&FOLDER) TYPE(*CHAR) LEN(10)
             DCLF       FILE(*LIBL/CVTODC1P)

 

             /* SET AS/400 FOLDER NAME HERE */
             CHGVAR     VAR(&FOLDER) VALUE('CODE')

 

             /*-------------------------------------*/
             /*CREATE FILE OF REPORTS IN USERS SPLF */
             /*-------------------------------------*/
             CLRPFM     FILE(CVTODC1P)
             WRKSPLF    OUTPUT(*PRINT)
             CPYSPLF    FILE(QPRTSPLF) TOFILE(*LIBL/CVTODC1P) +
                          SPLNBR(*LAST)

 

             /*-------------------------------------*/
             /*READ REPORT FILE UNTIL EOF           */
             /*-------------------------------------*/
 READLOOP:   RCVF       RCDFMT(SPLFO)

 

             MONMSG     MSGID(CPF0864) EXEC(GOTO CMDLBL(END)) /* +
                          check for EOF */

 

             /*-------------------------------------*/
             /*GET REPORT AND COPY TO FLAT FILE     */
             /*-------------------------------------*/
             CPYSPLF    FILE(&FILEN) TOFILE(*LIBL/CVTODC2P) +
                          JOB(&JOB#/&USER/&JOB) SPLNBR(*LAST)
             MONMSG     MSGID(CPF0001) EXEC(GOTO CMDLBL(READLOOP))

 

             /*----------------------------------------------*/
             /*COPY JOB LIST FOR CROSS REFERENCE W/DOCUMENT  */
             /*BECAUSE JOB# IS USED FOR DOCUMENT NAME.       */
             /*THIS IS DONE BECAUSE DUPLICATE REPORT NAMES   */
             /*WOULD OVERWRITE ONE ANOTHER, BUT THE JOB# IS  */
             /*DIFFERENT FOR EACH REPORT.                    */
             /*----------------------------------------------*/
             IF         COND(&FILEN *EQ 'QPRTSPLF') THEN(DO)
             CHGVAR     VAR(&FILET) VALUE('JOBLIST' *TCAT '.TXT')
             ENDDO
             ELSE       CMD(DO)
             CHGVAR     VAR(&FILET) VALUE((&JOB#) *TCAT '.TXT')
             ENDDO

 

             /*----------------------------------------------*/
             /*COPY TO FOLDER WITH A DOCUMENT NAME = JOB#    */
             /*----------------------------------------------*/
             CPYTOPCD   FROMFILE(CVTODC2P) TOFLR(&FOLDER) +
                          TODOC(&FILET) REPLACE(*YES)
             MONMSG     MSGID(CPF0001) EXEC(GOTO CMDLBL(READLOOP))

 

             /*----------------------------------------------*/
             /*GET NEXT REPORT                               */
             /*----------------------------------------------*/
             GOTO       CMDLBL(READLOOP)
 END:        ENDPGM