############################################################################
# 18 Dec 1998
# Start afresh
############################################################################
umask 022                       # disallow group and other write permission
unset ignoreeof                 # allow ctrl-d to logout
unset autologout                # keep me login 
set notify            
set history = 200
set savehist = 200
set filec
set fignore=(.o .tar .gz)       # user account should not see these files
############################################################################
# Additions for tcsh
############################################################################
set recexact
set autolist
set matchbeep=notunique
set noclobber
# msgs -q
limit core 0
limit coredumpsize 0
############################################################################
# aliases
# 31 Dec 1998 --- changed ls because of dircolors 
############################################################################
#alias ls       ls -F
eval `dircolors -c`
alias ll        ls -lasg
alias h         'history'
alias c         clear
alias cp        cp -i
alias f         finger
alias j         jobs
alias mv        mv -i
if ! $?prompt exit
############################################################################
# create tmpdir 
############################################################################
set tmpdir = ~/.wastebasket
if ! -e $tmpdir then
        echo $tmpdir has been deleted. Creating, ...
        mkdir $tmpdir
        chmod 755 $tmpdir
        echo $tmpdir created. 
        ls -al $tmpdir
else 
        echo Contents of $tmpdir
        ls -las $tmpdir
endif
############################################################################
# Now that the temporary directory has been set up, we can proceed 
# with our aliases
############################################################################
alias rr        'alias rm "mv \\!* $tmpdir"'
alias rm        'mv \!* $tmpdir'
alias ur        unalias rm
##############################################################
# these are bruce's aliases
##############################################################
set hname = `hostname` 
alias sp        'set prompt="$hname : $cwd:t % "'
sp
alias cd        'setenv old "$cwd"; chdir \!*; sp'
alias sc        'source ~/.cshrc'
alias sl        'source ~/.login'
alias popd      'popd; sp'
alias pd        'pushd \!*; sp'
alias back      'setenv t $old; cd $t'
alias find      'find /* -name \!* -exec ls -lasgF {} \; | grep \!* >& find_out &'
##############################################################
# these are for me
##############################################################
alias rs        'set noglob; eval `resize -c`; unset noglob'
alias df1       "df -k | awk -f dk.awk"
alias df2       "df -k | sort -br +1n -2 | awk -f df.awk"
##############################################################
# these are for ASOL, my Linux box
##############################################################
# 176  wget http://www.redbooks.ibm.com/SG245239/sg245239.html -r -o wget.log -nH -Y on -k --no-parent
# echo '\033c'
##############################################################
# 30 Dec 1998
# Why I cannot use Linux on a regular basis
# (a) abook.nab on exchange cannot be downloaded into Netscape
# (b) I need to download US versions of Netscape Communicator 4.5 
# (c) Need to setup printing services, perhaps Samba
# (d) No calendaring capability
##############################################################