function EntryPage::print_comment(Comment c) {
  var string symb;
  if ($c.metadata{"picture_keyword"}!=""){
    $symb = ": ";
  }
  var string picword;
  if (defined $c.userpic and $*comment_userpic_style !="off") {
    $picword = $c.poster.name + $symb + $c.metadata{"picture_keyword"};
  }
  var string datetime;
  $datetime = $c.time->date_format()+", " + $c.time->time_format();

  var string parent;
  var string thread;
  if($c.parent_url != "") {
    $parent = """<a href="$c.parent_url"> &nbsp; $*text_comment_parent &nbsp; </a>""";
  }
  if($c.thread_url != "") {
    $thread = """<a href="$c.thread_url"> &nbsp; $*text_comment_thread &nbsp; </a>""";
  }

  var string subjecticon;
  if (defined $c.subject_icon) {
    $subjecticon = """<img src="$c.subject_icon.url" width="$c.subject_icon.width" height="$c.subject_icon.height" height="$c.userpic.height" title='$picword'/>""";
  }

  var string ip;
  if ($c.metadata{"poster_ip"}) { 
    $ip = """ &nbsp;  """ + $c.metadata{"poster_ip"}; 
  }

  var string poster = defined $c.poster ? $c.poster->as_string() : "<b>(Anonymous)</b>";

  var string pic;
  if (defined $c.userpic and $*comment_userpic_style != "off") {
    $pic = """<div class="userpic2"><img src="$c.userpic.url" width="$c.userpic.width" height="$c.userpic.height" height="$c.userpic.height" title='$picword'/></div>""";
  }

  var string indent = ($c.depth - 1) * 25 + "px";
  """
  <a name="$c.anchor"></a>
  <div class="entry" style="margin-left: $indent;">
  $pic
  <div class="entryinfo"><br />$subjecticon</div>
  <div class="postedby">$poster <span class="ip">$ip</span></div>
  <div class="entryinfo"><b>on</b> $datetime</div>
  <div class="entrylinks">
  """;
  if ($.multiform_on) {
    """<label for="ljcomsel_$c.talkid">$*text_multiform_check</label> """; 
    $c->print_multiform_check();
  }

  var string replyurl;
  if ($c.frozen) {
    $replyurl = """ &nbsp; $*text_comment_frozen &nbsp; """;
  } else {
    $replyurl = """<a href="$c.reply_url"> &nbsp; $*text_comment_reply &nbsp; </a>""";
  }
  print $replyurl;

  # some links for doing stuff to this comment
  foreach var string k ($c.link_keyseq) {
    var Link link = $c->get_link($k);
    if ($link) {
      """<a href="$link.url"> &nbsp; $link.caption &nbsp; </a>""";
    }
  }
  """
  <a href="$c.permalink_url"> &nbsp; $*text_permalink &nbsp; </a>$parent$thread
  </div>
  <div class="entrytext">
    <div class="subject">$c.subject</div>
    <p>"""; $c->print_text(); """</p>
  </div>
  """;
  if ((size $c.replies) > 0 and $c.replies[0].full == false) {
    """<div style="margin-top: 5px; margin-bottom: 5px; clear: both;">\n""";
    $this->print_comments($c.replies);
    "</div>\n";
  }
  """
  </div>
  """;
  if ((size $c.replies) > 0 and $c.replies[0].full == true) {
    $this->print_comments($c.replies);
  }
}