Objetos, clases, instanciamiento

La siguientes explicaciones, del tipo tutorial, son más fáciles de entender si sigue los ejemplos en Visual FoxPro.

Una parte importante de la programación orientada a objetos son los objetos y las clases. Primero se define una clase como "modelo", después se ejecuta una "instancia" del objeto, que se llama clase. Por ejemplo, si utilizamos programación orientada a objetos para definir pantallas (forms), definimos una clase de tipo Form, y escribimos dentro todas las órdenes que deseamos, metemos controles (botones, TextBoxes, etc.), y definimos algunas propiedades (por ejemplo, .Height, .Width, .BackColor).

A continuación, un ejemplo de cómo definir un simple form en un programa, usando clases y objetos:

* Crear form con órdenes OOP

* Aquí estoy invocando el Form
public Form1 && Para esta prueba. De otra manera, al borrar la variable se borra el Form.
Form1 = CreateObject("cMiForm")
Form1.Visible = .T.
return

* Aquí se hace la definición del Form.
define class cMiForm as Form
   Height = 100
   Width = 150
   AutoCenter = .T.
   BackColor = RGB(255,0,0)
enddefine

Notas:

• cMiForm es el nombre de la clase. Es como un modelo; se podrían instanciar varias copias de este modelo (clase). En el ejemplo, sólo se instanció una vez; Form1 llega a ser un objeto. También se puede decir que Form1 es una instancia de la clase cMiForm.
• Form1 es una variable a través de la cual se puede manipular el Form.
• Inicialmente, Visual FoxPro hace que el Form sea invisible (propiedad Visible = .F.). La razón es que así podemos manipular el Form (u otro objeto), sin efectos visuales feos.

En realidad, normalmente es más fácil diseñar una clase en el diseñador de clases. Por ejemplo, para diseñar un Form como clase, es casi idéntico a diseñar un Form simple. (La principal excepción es que cuando se crea un como clase, no se dispone de DataEnvironment, y se tienen que abrir las tablas, fijar relaciones, índices y buffering en el evento Load).

Digamos que queremos definir el mismo Form como clase, en una librería de clases pruebas (nombre completo del archivo principal: pruebas.vcx).

Los pasos, para crear un Form similar al ejemplo anterior, son como sigue:

• Se abre un proyecto, o crea un nuevo proyecto.
• Se selecciona la sección "Classes".
• Se hace click en "New". Class Name = cMiForm, Based On = Form, Store In = Pruebas.
• En el Form que aparece, se hace click con el botón derecho del mouse, y se selecciona "Properties". En la hoja de propiedades que aparece, se cambian, siguiendo nuestro ejemplo, las propiedades .Height, .Width, .AutoCenter, .BackColor.
• Se graba.
• En la ventana de comandos, se pueden dar las siguientes órdenes:

set classlib to pruebas
local loForm1
loForm1 = CreateObject("cMiForm")
loForm1.Visible = .T.

Notas:

• SET CLASSLIB es similar a SET PROCEDURE: hace que Visual FoxPro sepa en qué archivos buscar una clase.
• Una librería de clases puede tener una clase, o varias.
• Tanto SET PROCEDURE como SET CLASSLIB ahora admiten una lista de archivos - ya no está restringido a usar una librería a la vez.
• El nombre loForm1 sigue los estándares recomendados: la primera letra indica el alcance de la variable (local), la segunda letra el tipo (objeto).

Para terminar esta breve introducción, debo mencionar otros tipos de clases y objetos. Algunos tienen presencia visual, como botones (CommandButton), marcas de verificación (CheckBox), campos de edición (TextBox y EditBox), y otros. Sin embargo, también hay objetos que no tienen representación visual - simplemente sirven como un conveniente repositorio para variables y funciones (es decir, Propiedades, Eventos y Métodos). Por ejemplo, para programar un juego, se puede tener un objeto "Jugador", con propiedades (variables) para nombre, puntaje actual, puntaje máximo, etc.; luego, se puede tener un array de esos objetos, para varios jugadores.

Volver a: Visual FoxPro | Página Principal de Hilmar Zonneveld